Botscript / Clonescan

[Cristian]

;# Trigger: .clonescan - command to trigger the script.
;# Its requires operator status to oprerate it.

;# Tested and works on version 6.15

Code: Select all

;# 
;# visit http://sp00fed.org for updates or support.
;# script by Sumsar
;#

on *:TEXT:.clonescan:#: {
  if ($nick isop $chan) {
    .raw -q privmsg $chan :Scanning for clones
    .raw -q WHO $chan
    hadd -m cscan chan $chan
  }
}
raw 352:*:{
  if ($2 == $hget(cscan,chan)) {
    haltdef
    if (!$hget(Clones,$4)) { hadd -m Clones $4 $6 }
    elseif ($hget(Clones,$4)) && (!$istok($hget(Clones,$4),$6,32)) { hadd -m Clones $4 $hget(Clones,$4) $6 }
  }
}
raw 315:*:{
  if ($2 == $hget(cscan,chan)) {
    haltdef
    if ($hget(Clones,0).item != 0) {
      var %q = $hget(Clones,0).item,%w = 1,%o = 1
      while (%w <= %q) {
        if ($numtok($hget(Clones,$hget(Clones,%w).item),32) > 1) {
          $+(.timer.,%w) 1 %o .raw -q privmsg $hget(cscan,chan) : $+([,$numtok($hget(Clones,$hget(Clones,%w).item),32),]) ( $+ $+(*!*@,$hget(Clones,%w).item) $+ ) $hget(Clones,$hget(Clones,%w).item) | inc %o 3
        }
        inc %w
      }
      $+(.timer.end) 1 $calc(%o + 3) .raw -q privmsg $hget(cscan,chan) : $+ End of Scan | hfree Clones | hfree cscan
    }
  }
}